[기출풀이] 컴활2급실기 2006년2회A형 기출문제 풀이-계산작업

컴활2급실기 2006년2회A형 기출문제의 계산작업니다. 계산작업은 함수를 기초로 하여 5문제가 출제 됩니다. 계산작업을 살펴봅니다.

해당기출문제다운로드:  컴활2급실기_06년2회A형.zip

문제2 계산작업(40점) ‘계산작업’시트에 대하여 다음 작업을 수행하고 저장하시오.

1. [표1]에서 구분이‘사탐’인 과목 중에서 표준편차[D3:D9]의 최고점수와 최저점수의 차이 값을 구하여[C12] 셀에 표시하시오. (8점)

▶ DMAX, DMIN, DSUM 함수 중 알맞은 함수를 선택하여 사용

▶ [B11:B12] 영역에 조건을 입력하여 함수 적용

풀이:

최고점수와 최저점수를 찾습니다. DMAX 함수  로 최고점수,DMIN 함수로 최저점수를 구합니다. 데이터베이스함수는 조건이 입력되는 조건범위가 필요합니다.  B11:B12 에 조건을 설정합니다.

C12 셀에 셀포인터를 놓고 다음의 수식을 입력합니다.

=DMAX(A2:D9,D2,B11:B12)-DMIN(A2:D9,D2,B11:B12)

최대값과 최소값을 구하여 그 차를 구하는 수식입니다.

A2:D9 의 데이터베이스범위에서 조건범위 B11:B12의 조건,  '구분' 이 '사탐' 을 만족하는 D2의 표준편차 필드에서 최대값을 구합니다.

DMIN함수를 사용하여 같은방법으로 최소값을 구하여 최대값에서 최소값의 차를 구합니다.

*데이터베이스함수는 필드부분을 범위에서의 열순번, 혹은 필드명,혹은 필드명의 셀번호 로 설정할수 있습니다. 또 조건은 반드시 범위로 설정하여야 하며 위와같이 조건을 직접입력하여야 하는 문제들도 있습니다.

2. [표2]에서 근태점수[G3:G12], 실적점수[H3:H12], 연수점수[I3:I12] 모두가 70 이상이면‘승진’그렇지 않으면 공란

으로 승진여부[J3:J12]에 표시하시오. (8점)

▶ IF와 AND 함수 사용

풀이:

조건이 셋이고 모든조건을 만족하여야 합니다.(AND함수) 모든조건 만족시 '승진' , 그렇지 않으면 공란입니다.

IF(조건,"승진","")

J3셀에 셀포인터를 놓고 다음의 수식을 입력합니다.

=IF(AND(G3>=70,H3>=70,I3>=70),"승진","")

입력후 J12셀까지 점끌기탭(채우기핸들)으로 수식복사합니다.

*IF함수로 조건비교하는 경우 조건이 여러개인 경우가 있습니다. 조건들을 모두 만족하여야 하는 경우는 AND함수를 하나의 조건이라도 참이되면 된다면 OR함수를 사용합니다. 조건이 여럿일 경우 조건들을 묶는 두함수 입니다. 잘 활용하셔야겠습니다.

3. [표3]에서 기록[C17:C22]에 대한 순위를 구하여 1위에는‘금’, 2위에는‘은’, 3위에는‘동’, 그 외에는 공란을 수상내역[D17:D22]에 표시하시오. (8점)

▶ 순위는 기록이 적은 팀이 1위

▶ CHOOSE와 RANK 함수 사용

풀이:

기록의 순위를 구하여 그 순위로 '금','은','동' 을 표시하고 4위부터는 공란을 표시합니다.

D17셀에 셀포인터를 놓고 다음의 수식을 입력합니다.

=CHOOSE(RANK(C17,$C$17:$C$22,1),"금","은","동","","","")

수식입력후 D22 까지 수식복사합니다.

먼저 순위를 구하는 RANK함수를 살펴봅니다. 기록범위 [C17:C22]  중에서 [C17] 셀의 순위를 오름차순으로 구합니다. 기록범위를 절대참조한 이유는 기록범위는 수식복사시에도 바뀌면 안되기 때문입니다. 또 순위를 구하는 방법을 1 (TRUE) 로 설정한 것은 문제에서 기록이 적은팀이 1위 로 되어있기 때문입니다. 이 말은 오름차순으로 순위를 구하라는 말입니다. RANK 함수는 순위를 구하는 방법인수를 생략하면 0(FALSE) 로 잡혀 내림차순으로 순위를 구합니다.

이렇게 구해진 순위를 CHOOSE함수의 색인값으로 사용합니다. 순위대로 금,은,동 이 반환됩니다.

"동" 뒤의 "" 들은 공란을 표시하기 위해서 입니다. 4위 5위 6위는 공란이 뜨는 것입니다. 순위를 구하는 전체 기록은 6개 인데 CHOOSE의 값들이 "동" 으로 끝나버리게 되면 에러가 뜨게 됩니다.

색인값으로 나올수 있는 수만큼 색인값뒤에 값들이 놓여야 한다는 말입니다.

예로 색인값이 1,2,3 일수 있는데  값이  '수' 와 '우' 로 둘 뿐이라면 색인값 3이 오게 되면 에러가 뜨게 되는 것입니다.

그래서 위에서는 값의 수를 RANK함수가 반환할수 있는 값의 수만큼 설정한 것입니다.

4. [표4]에서 도루[H17:H24]가 20 이상인 인원수와 홈런[I17:I24]이 20 이상인 인원수를 합하여 [H27] 셀에 표시하시오.

(8점)

▶ 표기 예 : 3명

▶ COUNTIF 함수와 & 연산자 사용

풀이:

조건을 만족하는 값들의 수를 세는 문제입니다.

도루가 20이상인 인원수를 셉니다.

=COUNTIF(H17:H24,">=20")

범위 [H17:H24] 에서 20이상인 수치셀을 계산합니다.

조건은 따옴표로 묶어 문자열 형식으로 입력합니다. 같은값을 찾을때는 부등호 생략하여도 좋습니다.

홈런이 20이상인 수도 범위만 다를뿐 위와 같습니다.

수식을 완성합니다. H27 셀에 셀포인터를 놓고 다음의 수식을 입력합니다.

=COUNTIF(H17:H24,">=20")+COUNTIF(I17:I24,">=20")&"명"

수식 마지막에 &(문자열연결 연산자) 를 이용하여 "명" 을 추가합니다.

5. [표5]에서 평가점수[C27:C35]에 대한 순위와 반배치표[A38:D39]를 이용하여 반배정[D27:D35]을 구하시오. (8점)

▶ 평가점수순위는 점수가 큰 사람이 1위

▶ 평가점수 순위가 1~3이면 A반, 4~6이면 B반, 7~9이면 C반으로 계산

▶ HLOOKUP과 RANK 함수 사용

풀이:

평가점수의 순위를 RANK 함수로 구하여 이 순위를 반배치표에서 찾아 반배정값을 얻습니다.

D27 셀에 셀포인터를 놓고 아래의 수식을 입력합니다.

=HLOOKUP(RANK(C27,$C$27:$C$35),$A$38:$D$39,2)

RANK함수를 이용해 먼저 순위를 구합니다.

C27셀의 평가점수를 C27:C35범위에서 순위를 구합니다. 순위를 구하는 방법은 내림차순입니다. 순위를 구하는방법인 RANK함수의 마지막인수를 생략하거나 FALSE 로 설정하면 내림차순으로 순위를 구합니다.

이렇게 순위를 구하여 이순위를  HLOOKUP함수를 이용하여 A38:D39의 반배치표의 첫행에서 찾아 2번째 행의 값을 반환합니다.

만일 찾는 값이 없다면 유사한값(찾는값보다 작은 가장 큰 값)을 찾습니다. HLOOKUP함수의 마지막 인수인 찾는방법인수가 생략되어 있기 때문입니다.

이렇게 유사한 값을 때는  찾는범위의 첫행이 오름차순정렬되어 있어야 합니다.

*** HLOOKUP함수나 VLOOKUP함수를 유사값으로 찾는 경우는 위와 같이 구간값을 찾는 경우입니다. 또 이때는 반드시 첫행이 오름차순 정렬되어 있어야 정확한 값을 얻을 수 있습니다.

마늘빵.