[기출풀이] 컴활2급실기 2006년1회A형 기출문제 풀이-계산작업

컴활2급실기 2006년1회A형 기출문제 계산작업입니다. 계산작업은 처음은 어려운듯 하지만 문제유형이 비슷하기에 기출문제를 풀어보시면서 계산작업의 함수를 익히시면 문제유형도 파악하시면서 함수를 학습하실수 있습니다.

해당기출문제다운로드: 

컴활2급실기_06년1회A형.zip

문제2 계산작업(40점) ‘계산작업’시트에 대하여 다음 작업을 수행하고 저장하시오.

1. [표1]의 주민번호[C3:C9]를 기준으로 성별[D3:D9]을 표시하시오. (8점)

▶ CHOOSE와 MID 함수 사용

▶ 주민번호 8번째 자리가 1 또는 3이면 ‘남’으로, 2 또는 4이면 ‘여’로 표시하시오.

풀이:

주민번호로 성별을 구하는 문제입니다. 값을 선택하는 함수인 CHOOSE함수와 문자열의 가운데서 임의 문자를 추출하는 함수인 MID함수를 사용합니다.

C3셀에 셀포인터를 놓고 다음의 수식을 입력합니다.

=CHOOSE(MID(C3,8,1),"남","여","남","여")

수식 입력후 C9 셀까지 점끌기탭(채우기핸들)을 이용하여 수식복사합니다.

수식을 분석해 보면 주민번호(C3)에서 8번째 자리가 성별을 구분하는 자리입니다. 이자리의 문자를 추출하기 위해 MID함수를 사용합니다.

MID(C3,8,1)  이 수식은 C3에서 8번째 1자리 를 추출합니다.  이를 CHOOSE 함수의 색인으로 사용합니다.

위의 수식에서 "남","여" 를 반복하여 두번 넣은 이유는 주민번호의 1과 3이 "남", 2와4가 "여" 이기때문이죠. CHOOSE 함수에서 색인값이 값들의 수보다 크게 되면 에러가 생깁니다.

예로 =CHOOSE( 5, "남1","여1","남2","여2") 이 수식은 값은 4개 뿐인데 색인값이 5이라 에러가 생기는 것입니다.

2. 현재년도와 [표2]의 결혼기념일을 이용해서 주년을 산출하고, 결혼기념일표[H13:I19]에서 주년에 해당되는 결혼기념명칭을 찾아 결혼기념[E13:E19]에 표시하시오. (8점)

▶ YEAR, TODAY, VLOOPUP 함수 사용

▶ 주년 = 현재년도 - 결혼년도

풀이:

현재일(TODAY함수)의 년도(YEAR함수)를 추출하여 위의 식대로 '주년' 을 계산하고 이값을 결혼기념일표에서 찾아 해당하는 결혼기념명칭을 찾습니다.(VLOOKUP함수)

E14셀에 셀포인터를 놓고 다음의 수식을 입력합니다.

=VLOOKUP(YEAR(TODAY())-YEAR(D13),$H$13:$I$19,2)

입력후 E19 까지 수식복사 합니다.

수식을 살펴보면 결혼기념일 표에서 찾을 값을 '주년' 입니다. 일단은 이를 알아야 하기에 문제의 방법대로 주년을 계산합니다.

현재년도는  TODAY()함수를 이용 오늘날짜를 얻고 YEAR함수로 년도를 추출하여 현재년도를 찾습니다. 결혼기념일셀(D13)에서 YEAR함수를 이용 년도를 추출하고 그 차를 구해 결혼기념일표[H13:H19] 에서 VLOOKUP함수를 이용하여 찾습니다.

결혼기념일표의 범위를 절대참조 하는 이유는 수식복사시 참조위치가 이동되는 것을 막기 위해서 입니다. 또 VLOOKUP함수에서 찾는방법을 설정하지 않은것은 찾는 값이 숫자이고 오름차순정렬되어 있기때문입니다.

이렇게 유사값을 찾을때는 찾는범위의 첫번째열이 오름차순 정렬되어있어야 한다는것 명심하세요.

3. [표3]에서 기록[D24:D31]에 대한 순위를 구하여 1위는 ‘1등’, 2위는 ‘2등’, 3위는 ‘3등’, 그 외에는 공란으로 등수[E24:E31]에 표시하시오. (8점)

▶ IF와 RANK 함수 사용, & 연산자 사용

▶ 순위는 기록이 가장 짧은 참가자가 1위

풀이:

순위를 구하여 그에해당하는 값을 출력하는 문제입니다.  조금은 생각을하셔야 하는 문제입니다. 1~3위 에 해당하는 값만을 출력하고 그렇지 않은 값은 공란을 표시합니다. 여기가 포인트 입니다.

E24셀에 셀포인터를 놓고 다음의 수식을 입력합니다.

=IF(RANK(D24,$D$24:$D$31,1)<=3,RANK(D24,$D$24:$D$31,1)&"등","")

입력후 E31셀까지 점끌기탭을 이용하여 수식복사합니다.

수식을 전체적으로 살펴보면 순위가 3위 이하이면 그 순위에 &(문자열연결 연산자) 를 이용하여 "등"을 추가하고 그렇지 않으면 공란을 표시합니다.

순위을 구하실때는 오름차순으로 구하기때문에 순위구하는 방법 옵션을 1(TRUE) 로 설정하였습니다.

4. [표4]에서 ‘빌리지힐’의 평균 매매가를 구하여 [D45]에 표시하시오. (8점)

▶ DAVERAGE 함수 사용

풀이:

데이터베이스함수를 이용하여 평균을 구합니다.

D45 셀에 셀포인터를 놓고 다음의 수식을 입력합니다.

=DAVERAGE(B34:E43,E34,B34:B35)

데이터베이스범위 B34:E43 에서 조건범위 B34:35 와 일치하는 레코드(행)이 있으면 E34 '매매가(만원)' 열의 평균을 구합니다.

열을 입력하는 방법은 범위에서의 열순번, 열레이블, 열레이블의 주소 등이 있습니다.

5. [표5]에서 건구온도와 습구온도를 이용하여, 불쾌지수[E50:E56]를 표시하시오. (8점)

▶ 불쾌지수 = (건구온도 + 습구온도) × 0.72 + 40.6

▶ 불쾌지수는 정수로 표시하시오. [표시 예 : 66.736 → 66]

▶ ABS, INT, FACT, RAND, PI 중 알맞은 함수 사용

풀이:

위의 식대로 불쾌지수를 구하고 이를 정수로 표시하는 문제입니다. 사용가능함수중 정수화 하는 함수는 INT함수입니다.

ABS함수는 절대값을 구하는 함수이고 FACT함수는 팩토리얼을 RAND함수는 랜덤값을 얻는 함수입니다. PI함수는 원주율을 얻는 함수입니다.

E50 셀에 셀포인터를 놓고 다음의 수식을 입력합니다.

=INT((C50+D50)*0.72+40.6)

수식을 입력하고 점끌기탭(채우기핸들)을 이용하여 수식복사합니다.

위의 수식은 문제에서 불쾌지수를 구하는 식대로 식을 작성한후 INT함수로 둘러 정수화 한것 밖에 없습니다.

INT함수는 인수보다 작은 값으로 자리내림하여 정수화 합니다.

이와 유사한 함수로 TRUNC 함수가 있는데 이함수는  소수이하는 버리고 정수부만을 취하는 방법으로 정수화합니다.


마늘빵.